| ZER DAKIDAN: Array laguntzaile batean oinarrituriko hiru algoritmo 28. Ariketa: fitxategiak (IV) atalean ikasi ditut, eta fitxategi laguntzaile batean oinarrituriko bi algoritmo 29. Ariketa: fitxategiak (V) atalean ikasi ditut. ZER IKASIKO DUDAN: Erregistroen fitxategi batean, fitxategia nola sailkatu ikasiko dut bere elementuak ordenatuz. Datuen fitxategia sailkatzeko array laguntzaile bat erabili ordez, fitxategi laguntzaile bati esker nola egin daitekeen ikasiko dut. |
ESKATZEN DEN PROGRAMA
Erregistroen fitxategi batekin lan egingo dugu eta sailkatze algoritmoa aplikatuko diogu fitxategiari. Fitxategiaren elementuak hiru eremuko erregistroak izango dira. Lehen eremua ibilgailuaren matrikula izango da (matrikula guztien letrak BPK edo KHS izango dira auzaz hautaturik, eta matrikulen 4 zifrak programak aukeratuko ditu ere (programak zainduko du ibilgailuen matrikulak ez direla errepikatzen fitxategian). Bigarren eremua ibilgailuaren mota adierazteko karaktere bat izango da eta auzaz esluratuko du programak. Hirugarren eremua aldiuneko abiadura izango da eta bere balio erreala auzaz lortuko dugu ere.
Erregistroaren egitura honako hau da:
| 1. eremua | sMatrikula | 8 karaktereko kate bat, 'ZZZZ LLL' formatuko kate desberdinak izango dira fitxategiaren elementu guztientzat |
| 2. eremua | cIbilgailuMota | karaktere bat |
| 3. eremua | rAldiunekoAbiadura | zenbaki erreal bat |
Gure programak fitxategiaren izena eskatuko du (Automobilak.dat adibidez) hainbat elementuren informazioa gordeko du. Datuen fitxategia abiaduren arabera sailkatu nahi da baina array laguntzailerik gabe, datu-egitura laguntzailea beste fitxategi bat izango da, Laguna.dat izeneko fitxategia esate baterako.
Fitxategi bat sailkatzeko edozein algoritmotan datu-egitura laguntzaile bat behar-beharrezkoa da, baina zein motatako laguntzailea? Datu-egitura laguntzailea array bat denean, hasierako fitxategiak biltzen dituen elementuen kopuru maximoa arrayaren neurrira mugaturik egon behar da derrigorrez. Baina datu-egitura laguntzailea beste fitxategi bat denean, hasierako fitxategiaren elementuen kopuruak ez dauka inongo mugarik.
Hauxe da ariketaren programa:
{ 30. ariketa: auto bat radar atari azpitik igartzean ondoko datuak }
{ jaso eta gordetzen dira fitxategi batean: }
{ - Matrikula, karkatere-kate bat }
{ - Ibilgailu mota, karaktere bat }
{ - Aldi uneko abiadura, zenbaki erreal bat }
{ Datuak erdi automatikoki lortuko dira auzazko balioak sortuz. }
{ Matrikula bereko autoak ez direlako onartzen, matrikula jakin bat }
{ sortzean, fitxategian berria izango dela frogatu beharra dago. }
{ Fitxategia existitzen ez bada, sortuko da eta datuz bete ondoren }
{ bere edukia pantailaratuko da. Fitxategia lehendik existitzen bada }
{ duen edukia pantailaratuko da. }
{ Datuen fitxategia lortu eta gero, abiaduren arabera sailkatuko da }
{ abiadura handiak lehenak jarriz. }
{ Egitura laguntzailearen datu-mota: file }
program Ariketa_30 ;
uses
sysutils; { fileExists() funtzioak behar duelako }
const
//sBIDEA = 'C:\Radarrak\'; (* Windows *)
sBIDEA = '/Users/jesusromouriarte/Desktop/Radarrak/'; (* Mac *)
type
tsKatea = string[250]; { Fitxategiaren izen osoa luzea izan daitekeelako }
tsKateMatrikula = string[8] ; { ZZZZ LLL formatuko matrikula }
tsKateZifrak = string[4] ; { Matrikularen ZZZZ zatirako }
trdIbilgailua = record
sMatrikula : tsKateMatrikula ;
cIbilgailuMota : char ;
rAldiunekoAbiadura: real ;
end ;
tfrdFitxategia = file of trdIbilgailua ;
trdLaguntzailea = record
sMatrikula : tsKateMatrikula ;
cIbilgailuMota : char ;
rAldiunekoAbiadura: real ;
boProzesatuta : boolean ;
end ;
tfrdLaguntzailea = file of trdLaguntzailea ;
procedure IbilgailuarenInformazioaErakutsi(const rdIbilgailua: trdIbilgailua) ;
begin
write(rdIbilgailua.sMatrikula:15) ;
write(rdIbilgailua.cIbilgailuMota:9) ;
write(rdIbilgailua.rAldiunekoAbiadura:14:2) ;
writeln ;
end ;
procedure LaguntzailearenInformazioaErakutsi(const rdLaguntzailea: trdLaguntzailea) ;
begin
write(rdLaguntzailea.sMatrikula:15) ;
write(rdLaguntzailea.cIbilgailuMota:9) ;
write(rdLaguntzailea.rAldiunekoAbiadura:14:2) ;
write(rdLaguntzailea.boProzesatuta:13) ;
writeln ;
end ;
procedure FitxategiarenEdukiaIkusi(sFitxIzen: tsKatea) ;
var
f: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
begin
assign(f, sFitxIzen) ;
reset(f) ;
writeln('Matrikula Mota':47, 'Abiadura':14) ;
writeln('--------- ----':47, '--------':14) ;
while not eof(f) do
begin
read(f,rdDatua) ;
write(filePos(f):10, '. elementua: ') ;
IbilgailuarenInformazioaErakutsi(rdDatua) ;
end ;
close(f) ;
end ;
procedure LaguntzailearenEdukiaIkusi(sFitxIzen: tsKatea) ;
var
f: tfrdLaguntzailea ;
rdLaguntzailea: trdLaguntzailea ;
begin
assign(f, sFitxIzen) ;
reset(f) ;
writeln('Matrikula Mota':47, 'Abiadura':14, 'Prozes.':13) ;
writeln('--------- ----':47, '--------':14, '-------':13) ;
while not eof(f) do
begin
read(f,rdLaguntzailea) ;
write(filePos(f):10, '. elementua: ') ;
LaguntzailearenInformazioaErakutsi(rdLaguntzailea) ;
end ;
close(f) ;
end ;
procedure IbilgailuarenInformazioaJaso(var rdIbilgailua: trdIbilgailua) ;
var
iAusazkoa, iKont: integer ;
sMatrikula, sMatrikulaZifra: tsKateMatrikula ;
begin
sMatrikula := '' ;
for iKont:=1 to 4 do
begin
iAusazkoa := random(10) ;
Str(iAusazkoa, sMatrikulaZifra) ;
sMatrikula := sMatrikula + sMatrikulaZifra ;
end ;
iAusazkoa := random(3) ;
case iAusazkoa of
0: rdIbilgailua.sMatrikula := sMatrikula + ' BPK' ;
1: rdIbilgailua.sMatrikula := sMatrikula + ' KHS' ;
2: rdIbilgailua.sMatrikula := sMatrikula + ' PXS' ;
end ;
iAusazkoa := random(4) ;
case iAusazkoa of
0: rdIbilgailua.cIbilgailuMota := 'A' ;
1: rdIbilgailua.cIbilgailuMota := 'B' ;
2: rdIbilgailua.cIbilgailuMota := 'C' ;
3: rdIbilgailua.cIbilgailuMota := 'D' ;
end ;
rdIbilgailua.rAldiunekoAbiadura := 50 + 130*random; (* 50.0 eta 179.99 artean *)
end ;
procedure FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
rewrite(f) ; { Fitxategia sortu }
write(f, rdIbilgailua) ; { Lehen elementua gorde }
close(f) ; { Fitxategia itxi }
end ;
procedure FitxategianElementuBatGehitu(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki baina barrukoa ez borratu!!! }
seek(f, fileSize(f)) ; { Fitxategiaren bukaeran kokatu }
write(f, rdIbilgailua) ; { Fitxategian idatzi eta hurrengo elementura pasa }
close(f) ; { Fitxategia itxi }
end ;
{ Bilaketa gauzatzeko funtzioan while-DO egitura erabiltzen da }
function fniMatrikulaFitxategianBilatu(sFitxIzen: tsKatea; sMatrik: tsKateMatrikula): integer ;
var
f: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
boAurkitua: boolean ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki baina barrukoa ez borratu!!! }
boAurkitua := FALSE ;
while not eof(f) and not boAurkitua do
begin
read(f,rdDatua) ;
if rdDatua.sMatrikula = sMatrik then
boAurkitua := TRUE
end ;
if boAurkitua then
fniMatrikulaFitxategianBilatu := filePos(F) - 1
else
fniMatrikulaFitxategianBilatu := -1 ; { -1 gezurrezko posizioa litzateke }
close(f) ; { Fitxategia itxi }
end ;
procedure FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen: tsKatea) ;
var
rdIbilgailua: trdIbilgailua ;
iZenbat, iIndizea, iPosizioa: integer ;
begin
repeat
write('Zenbat elementu izango ditu fitxategiak (adibidez 150): ') ;
readln(iZenbat) ;
until iZenbat > 0 ;
writeln ;
randomize ;
IbilgailuarenInformazioaJaso(rdIbilgailua) ;
FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen, rdIbilgailua) ; { Lehen matrikula beti izango da berria }
for iIndizea:=2 to iZenbat do
begin
repeat
IbilgailuarenInformazioaJaso(rdIbilgailua) ;
iPosizioa := fniMatrikulaFitxategianBilatu(sFitxIzen, rdIbilgailua.sMatrikula) ;
if iPosizioa <> -1 then
begin
writeln('''', rdIbilgailua.sMatrikula, ''' matrikula fitxategiaren ', iPosizioa, '. posizioan dago!!!') ;
writeln('Aurrera egiteko RETURN sakatu!') ;
readln ;
end
else
FitxategianElementuBatGehitu(sFitxIzen, rdIbilgailua) ; { Matrikula berria da }
until iPosizioa = -1 ;
end ;
end ;
function fnbo4ZifraDira(sMatrikulaZifrak: tsKateZifrak): boolean ;
var
k: integer ;
boBai4ZifraDira: boolean ;
begin
boBai4ZifraDira := TRUE ;
for k:=1 to 4 do
begin
if (sMatrikulaZifrak[k] <'0') or (sMatrikulaZifrak[k] > '9') then
begin
writeln(k, '. posizioko ''', sMatrikulaZifrak[k], ''' karakterea ez da zifra bat, 4 zifrak errepikatu.') ;
boBai4ZifraDira := FALSE ;
end ;
end ;
fnbo4ZifraDira := boBai4ZifraDira ;
end ;
procedure MatrikulaZehaztu(var sMatrikulaBat: tsKateMatrikula) ;
var
sMatrikulaZifrak: tsKateZifrak ;
cHautapena: char ;
begin
repeat
write('Matrikularen ZZZZ lau zifrak eman: ') ;
readln(sMatrikulaZifrak) ;
until fnbo4ZifraDira(sMatrikulaZifrak) ;
writeln('Matrikularen letrak ''BPK'' edo ''KHS'' direnez, bat hautatu:') ;
writeln(' ''BPK'' bada 1 aukeratu') ;
writeln(' ''KHS'' bada 2 aukeratu') ;
repeat
write('Zure hautapena aukeratu -----> ') ;
readln(cHautapena) ;
until (cHautapena = '1') or (cHautapena = '2') ;
if cHautapena = '1' then
sMatrikulaBat := sMatrikulaZifrak + ' BPK'
else
sMatrikulaBat := sMatrikulaZifrak + ' KHS' ;
end ;
procedure FitxategiLaguntzaileaLortu(sFitxIzen, sFitxIzenLagun: tsKatea) ;
var
f : tfrdFitxategia ;
rdDatua : trdIbilgailua ;
fLaguntzailea : tfrdLaguntzailea ;
rdDatuLaguntzailea : trdLaguntzailea ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki }
assign(fLaguntzailea, sFitxIzenLagun) ;
rewrite(fLaguntzailea) ; { Fitxategi laguntzailea sortu }
while not eof(f) do
begin
read(f, rdDatua) ; { Fitxategitik elementu osoa irakurri }
rdDatuLaguntzailea.sMatrikula := rdDatua.sMatrikula ;
rdDatuLaguntzailea.cIbilgailuMota := rdDatua.cIbilgailuMota ;
rdDatuLaguntzailea.rAldiunekoAbiadura := rdDatua.rAldiunekoAbiadura ;
rdDatuLaguntzailea.boProzesatuta := FALSE ;
write(fLaguntzailea, rdDatuLaguntzailea) ; { Elementua laguntzailean gorde }
end ;
close(f) ; { Fitxategia itxi }
close(fLaguntzailea) ; { Laguntzailea itxi }
end ;
procedure DatuenFitxategiaTrunkatu(sFitxIzen: tsKatea) ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
reset(f) ;
truncate(f) ; { Fitxategi laguntzaileak datuak dituelako ez dira galdu }
close(f) ; { Fitxategia itxi }
end ;
procedure MaximoaFitxategianGorde(sFitxIzen, sFitxIzenLagun: tsKatea; liNon: longint) ;
var
f : tfrdFitxategia ;
rdDatua : trdIbilgailua ;
fLaguntzailea : tfrdLaguntzailea ;
rdDatuLaguntzailea : trdLaguntzailea ;
begin
assign(f, sFitxIzen) ;
reset(f) ;
assign(fLaguntzailea, sFitxIzenLagun) ;
reset(fLaguntzailea) ; { Fitxategi laguntzailea ireki }
seek(fLaguntzailea, liNon) ;
read(fLaguntzailea, rdDatuLaguntzailea) ;
//writeln('Laguntzailetik irakurria: liNon = ', liNon, ' sMatrikula = ', rdDatuLaguntzailea.sMatrikula) ;
rdDatua.sMatrikula := rdDatuLaguntzailea.sMatrikula ;
rdDatua.cIbilgailuMota := rdDatuLaguntzailea.cIbilgailuMota ;
rdDatua.rAldiunekoAbiadura := rdDatuLaguntzailea.rAldiunekoAbiadura ;
seek(f, fileSize(f)) ;
write(f, rdDatua) ;
close(f) ; { Fitxategia itxi }
close(fLaguntzailea) ; { Laguntzailea itxi }
end ;
function fnliMaximoarenPosizioaZehaztu(sFitxIzen: tsKatea): longint ;
var
fLaguntzailea : tfrdLaguntzailea ;
rdElem : trdLaguntzailea ;
rMaximoa : real ;
liMaximoaNon : longint ;
begin
assign(fLaguntzailea, sFitxIzen) ;
reset(fLaguntzailea) ; { Irakurketa-Idazketarako ireki }
rMaximoa := -1.0 ; { Izan daitekeen txikiena baino txikiagoa, abiadura mininimoa 50.0 KM da }
liMaximoaNon := -1 ;
while not eof(fLaguntzailea) do
begin
read(fLaguntzailea, rdElem) ; { Fitxategitik irakurri }
if (rdElem.rAldiunekoAbiadura > rMaximoa) and (not rdElem.boProzesatuta) then
begin
rMaximoa := rdElem.rAldiunekoAbiadura ;
liMaximoaNon := filePos(fLaguntzailea) - 1 ; { Erakuslea dagoen posizioaren aurrekoa }
end
end ;
if liMaximoaNon <> -1 then
begin
seek(fLaguntzailea, liMaximoaNon) ;
read(fLaguntzailea, rdElem) ;
rdElem.boProzesatuta := TRUE ;
seek(fLaguntzailea, liMaximoaNon) ;
write(fLaguntzailea, rdElem) ;
write('Maximoa ----->':23) ;
LaguntzailearenInformazioaErakutsi(rdElem) ;
fnliMaximoarenPosizioaZehaztu := liMaximoaNon ;
end
else
begin
writeln(' Maximoen prozesaketak bukatuta, laguntzailea honela geratu da:') ;
fnliMaximoarenPosizioaZehaztu := -1 ;
end ;
close(fLaguntzailea) ; { Fitxategia itxi }
end ;
procedure FitxategiaAbiadurazSailkatu(sFitxIzen, sFitxIzenLagun: tsKatea) ;
var
liAbiaduraMaxNon : longint ;
begin
FitxategiLaguntzaileaLortu(sFitxIzen, sFitxIzenLagun) ;
writeln('=============================================================================') ;
writeln('Fitxategi laguntzailearen edukia:') ;
LaguntzailearenEdukiaIkusi(sFitxIzenLagun) ;
writeln('=============================================================================') ;
writeln ;
writeln('Aurrera egiteko RETURN sakatu') ;
readln ;
writeln ;
DatuenFitxategiaTrunkatu(sFitxIzen) ; { Fitxategi laguntzaileak datuak ditu }
repeat
liAbiaduraMaxNon := fnliMaximoarenPosizioaZehaztu(sFitxIzenLagun) ;
writeln('-----------------------------------------------------------------------------') ;
LaguntzailearenEdukiaIkusi(sFitxIzenLagun) ;
writeln ;
writeln(' liAbiaduraMaxNon = ', liAbiaduraMaxNon);
writeln('-----------------------------------------------------------------------------') ;
writeln ;
writeln ;
if liAbiaduraMaxNon <> -1 then
MaximoaFitxategianGorde(sFitxIzen, sFitxIzenLagun, liAbiaduraMaxNon) ;
until liAbiaduraMaxNon = -1 ;
end ;
procedure LaguntzaileaEzabatu(sFitxIzenLagun: tsKatea) ;
var
fLaguntzailea: tfrdLaguntzailea ;
begin
assign(fLaguntzailea, sFitxIzenLagun) ;
Erase(fLaguntzailea) ;
end ;
(* ---------------------- PROGRAMA NAGUSIA ---------------------- *)
var
sFitxIzen, sFitxIzenLagun: tsKatea ;
begin
writeln ;
writeln ;
writeln ;
writeln('Ibilgailuen informazioa gordeko duen fitxategiaren izena eman ezazu.') ;
write('Adibidez, ''Automobilak.dat'' izena: ') ;
readln(sFitxIzen) ;
sFitxIzen := sBIDEA + sFitxIzen ;
writeln ;
if fileExists(sFitxIzen) then { Konprobatu ea existitzen den ala ez }
begin
writeln(sFitxIzen, ' fitxategia existitzen da.') ;
writeln('=============================================================================') ;
writeln('Hona hemen bere edukia:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
end
else
begin
writeln(sFitxIzen, ' fitxategirik ez dago.') ;
writeln('Oraintxe sortuko dugu.') ;
FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen) ;
writeln('=============================================================================') ;
writeln('Sortutako fitxategiaren edukia:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
end ;
sFitxIzenLagun := sBIDEA + 'Laguna.dat' ;
FitxategiaAbiadurazSailkatu(sFitxIzen, sFitxIzenLagun) ;
LaguntzaileaEzabatu(sFitxIzenLagun) ;
writeln ;
writeln('Sailkatutako fitxategiaren edukia:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
writeln ;
write('RETURN sakatu programa bukatzeko') ;
writeln ;
readln ;
end.
Programaren balizko exekuzio bat hurrrengo hiru irudien artean erakusten da:
iruzkinik ez:
Argitaratu iruzkina
Iruzkinen bat idazteko Google-ko kontu bat behar duzu. Iruzkin guztien moderazio-ardura blogeko administratzaileari dagokio.