27. Ariketa: fitxategiak (III)

ZER DAKIDAN:
Zenbakiak, karaktereak, kateak, arrayak, erregistroak eta fitxategiak lantzeko gai naiz.
Erregistroen fitxategi batean ondoko operazioak nola egin badakit:

Fitxategiaren existentzia konprobatu fileexits funtzioaren bitartez
Fitxategiaren bukaera konprobatu eof funtzioaren bitartez
Fitxategiaren erakuslea dagoen posizioa konprobatu filepos funtzioaren bitartez
Fitxategiaren erakuslea dagoen posiziotik aldatu seek prozeduraren bitartez
Fitxategiaren elementuen kopurua konprobatu filesize funtzioaren bitartez
Fitxategia moztu truncate prozeduraren bitartez
Fitxategia diskotik ezabatu erase prozeduraren bitartez
Fitxategia berrizendatu diskoan rename prozeduraren bitartez

Algoritmoak ikas ditzagun atal honetan.

ZER IKASIKO DUDAN:
Erregistroen fitxategi batean, ondoko algoritmoak programatzen ikasiko dut ez array laguntzaile, ez fitxategi laguntzailerik gabe:

Fitxategi osoa prozesatu
Bilaketa fitxategian
Elementu berriak fitxategira gehitu
Fitxategiaren elementu baten balioren bat aldatu

Array laguntzaile batean oinarritutako algoritmoak hurrengo 28. ariketa: fitxategiak (IV) atalean ikasiko ditut.

ESKATZEN DEN PROGRAMA

Erregistroen fitxategi batekin lan egingo dugu eta algoritmo batzuk aplikatuko dizkiogu fitxategiari. Fitxategiaren elementuak hiru eremuko erregistroak izango dira. Lehen eremua ibilgailuaren matrikula izango da (matrikula guztien letrak BPK edo KHS izango dira auzaz hautaturik, eta matrikulen 4 zifrak programak aukeratuko ditu ere (programak zainduko du ibilgailuen matrikulak ez direla errepikatzen fitxategian). Bigarren eremua ibilgailuaren mota adierazteko karaktere bat izango da eta auzaz esluratuko du programak. Hirugarren eremua aldiuneko abiadura izango da eta bere balio erreala auzaz lortuko dugu ere.

Erregistroaren egitura honako hau da:

1. eremua	sMatrikula	8 karaktereko kate bat, 'ZZZZ LLL' formatuko kate desberdinak izango dira fitxategiaren elementu guztientzat
2. eremua	cIbilgailuMota	karaktere bat
3. eremua	rAldiunekoAbiadura	zenbaki erreal bat

Gure programak fitxategiaren izena eskatuko du (Kamioak.dat adibidez) eta erabiltzaileak emandako sarrerarekin fitxategiaren existentzia konprobatuko du, ondoko bi bide irekiz:

Kamioak.dat fitxategia existitzen bada, bere edukia pantailaratuko da
Kamioak.dat fitxategia existitzen ez bada, fitxategi berria sortuko da 25. Ariketa: fitxategiak (I) programan bezalaxe, baina oraingoan matrikulak ez dira sekuentzialak izango. Ondoren, sortu berri den fitxategiaren edukia pantailaratuko da

Bide batetik zein bestetik igaroz Kamioak.dat fitxategiak hainbat elementuren informazioa gordeko du eta elementu bati bere abiaduraren balioa aldatuko zaio. Horretarako, teklatuz eman beharreko matrikula bat eskatuko da eta matrikula horren bilaketari fitxategian ekingo zaio. Emandako matrikulako ibilgailurik aurkitzen bada fitxategian bere abiadura inkrementatuko da %10ean.

Hauxe da ariketaren programa:

{ 27. ariketa: auto bat radar atari azpitik igartzean ondoko datuak   }
{              jaso eta gordetzen dira fitxategi batean:              }

{     - Matrikula, karkatere-kate bat                                 }
{     - Ibilgailu mota, karaktere bat                                 } 
{     - Aldi uneko abiadura, zenbaki erreal bat                       }
                       
{  Datuak erdi automatikoki lortuko dira auzazko balioak sortuz.      }
{  Matrikula bereko autoak ez direlako onartzen, matrikula jakin bat  }
{  sortzean, fitxategian berria izango dela frogatu beharra dago.     } 

{  Fitxategia existitzen ez bada, sortuko da eta datuz bete ondoren   }
{  bere edukia pantailaratuko da. Fitxategia lehendik existitzen bada }
{  duen edukia pantailaratuko da.                                     }

{  Fitxategia lortuta, matrikula jakin bateko ibilgailuari dagokion   }
{  abiadura aldatuko zaio (bere %10a inkrementatuz).                  }                   

program Ariketa_27 ;

uses
   sysutils;    { fileExists() funtzioak behar duelako }
   
const
   //sBIDEA = 'C:\Radarrak\';                              (* Windows *)
   sBIDEA = '/Users/jesusromouriarte/Desktop/Radarrak/';   (* Mac *)

type
   tsKatea = string[250];           { Fitxategiaren izen osoa luzea izan daitekeelako }
   
   tsKateMatrikula = string[8] ;    { ZZZZ LLL formatuko matrikula }
   
   tsKateZifrak = string[4] ;       { Matrikularen ZZZZ zatirako }
              
   trdIbilgailua = record
                      sMatrikula        : tsKateMatrikula ;
                      cIbilgailuMota    : char ;
                      rAldiunekoAbiadura: real ;
                   end ;
    
   tfrdFitxategia = file of trdIbilgailua ;


procedure IbilgailuarenInformazioaErakutsi(const rdIbilgailua: trdIbilgailua) ;
begin
   write(rdIbilgailua.sMatrikula:15) ;
   write(rdIbilgailua.cIbilgailuMota:9) ; 
   write(rdIbilgailua.rAldiunekoAbiadura:14:2) ;      
   writeln ;
end ;


procedure FitxategiarenEdukiaIkusi(sFitxIzen: tsKatea) ;
var
   f: tfrdFitxategia ;
   rdDatua: trdIbilgailua ;
begin
   assign(f, sFitxIzen) ;
   reset(f) ;    { Fitxategia ireki baina barrukoa ez borratu!!! }

   writeln('Matrikula     Mota':47, 'Abiadura':14) ;
   writeln('---------     ----':47, '--------':14) ;
   
   { Datuak kudeatu for bitartez} 
   while not eof(f) do  
   begin
      read(f,rdDatua) ;    { Irakurri eta hurrengora pasa }
      write(filePos(f):10, '. elementua: ') ;
      IbilgailuarenInformazioaErakutsi(rdDatua) ;
   end ;

   close(f) ;     { Fitxategia itxi }
end ;


procedure IbilgailuarenInformazioaJaso(var rdIbilgailua: trdIbilgailua) ;
var
   iAusazkoa, iKont: integer ;
   sMatrikula, sMatrikulaZifra: tsKateMatrikula ;
begin
   sMatrikula := '' ;
   for iKont:=1 to 4 do
   begin
      iAusazkoa := random(10) ;
      Str(iAusazkoa, sMatrikulaZifra) ;
      sMatrikula := sMatrikula + sMatrikulaZifra ;        
   end ;

   iAusazkoa := random(2) ;
   case iAusazkoa of
      0: rdIbilgailua.sMatrikula := sMatrikula + ' KHS' ;
      1: rdIbilgailua.sMatrikula := sMatrikula + ' BPK' ;
   end ;

   iAusazkoa := random(4) ;
   case iAusazkoa of
      0: rdIbilgailua.cIbilgailuMota := 'A' ;
      1: rdIbilgailua.cIbilgailuMota := 'B' ;
      2: rdIbilgailua.cIbilgailuMota := 'C' ;
      3: rdIbilgailua.cIbilgailuMota := 'D' ;
   end ;

   rdIbilgailua.rAldiunekoAbiadura := 50 + 130*random;   (* 50.0 eta 179.99 artean *)
end ;


procedure FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
   f: tfrdFitxategia ;
begin
   assign(f, sFitxIzen) ;
   rewrite(f) ;              { Fitxategia sortu }
   write(f, rdIbilgailua) ;  { Lehen elementua gorde } 
   close(f) ;                { Fitxategia itxi }
end ;


procedure FitxategianElementuBatGehitu(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
   f: tfrdFitxategia ;
begin
   assign(f, sFitxIzen) ;
   reset(f) ;               { Fitxategia ireki baina barrukoa ez borratu!!! }    
   seek(f, fileSize(f)) ;   { Fitxategiaren bukaeran kokatu }
   write(f, rdIbilgailua) ; { Fitxategian idatzi eta hurrengo elementura pasa }
   close(f) ;               { Fitxategia itxi }
end ;
   
   
{ Bilaketa gauzatzeko funtzioan while-DO egitura erabiltzen da }
function fniMatrikulaFitxategianBilatu(sFitxIzen: tsKatea; sMatrik: tsKateMatrikula): integer ;
var
   f: tfrdFitxategia ;
   rdDatua: trdIbilgailua ;
   boAurkitua: boolean ;
begin
   assign(f, sFitxIzen) ;
   reset(f) ;    { Fitxategia ireki baina barrukoa ez borratu!!! }

   boAurkitua := FALSE ;
   while not eof(f) and not boAurkitua do  
   begin
      read(f,rdDatua) ;    { Irakurri eta hurrengora pasa }    
      if rdDatua.sMatrikula = sMatrik then
         boAurkitua := TRUE
   end ;
   
   if boAurkitua then
     fniMatrikulaFitxategianBilatu := filePos(F) - 1
   else
     fniMatrikulaFitxategianBilatu := -1 ;     { -1 gezurrezko posizioa litzateke }

   close(f) ;     { Fitxategia itxi }
end ;


procedure FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen: tsKatea) ;
var
   rdIbilgailua: trdIbilgailua ; 
   iZenbat, iIndizea, iPosizioa: integer ;
begin
   repeat
      write('Zenbat elementu izango ditu fitxategiak (adibidez 250): ') ;
      readln(iZenbat) ;
   until iZenbat > 0;
   writeln ;
   
   randomize ;
   IbilgailuarenInformazioaJaso(rdIbilgailua) ;
   FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen, rdIbilgailua) ;   { Lehen matrikula beti izango da berria }
    
   for iIndizea:=2 to iZenbat do
   begin
      repeat
         IbilgailuarenInformazioaJaso(rdIbilgailua) ;
         iPosizioa :=  fniMatrikulaFitxategianBilatu(sFitxIzen, rdIbilgailua.sMatrikula) ;
      
         if iPosizioa <> -1 then
         begin
            writeln('''', rdIbilgailua.sMatrikula, ''' matrikula fitxategiaren ', iPosizioa, '. posizioan dago!!!') ;
            writeln('Aurrera egiteko RETURN sakatu!') ;
            readln ;
         end   
         else
            FitxategianElementuBatGehitu(sFitxIzen, rdIbilgailua) ;   { Matrikula berria da }   
      until iPosizioa = -1 ;
   end ;
end ;


procedure FitxategianElementuBatAldatu(sFitxIzen: tsKatea; iPosizioa: integer) ;
var
   f: tfrdFitxategia ;
   rdIbilgailua: trdIbilgailua ;
   rAbiadura: real ; 
begin
   assign(f, sFitxIzen) ;
   reset(f) ;               { Fitxategia ireki baina barrukoa ez borratu!!! }    
   seek(f, iPosizioa) ;     { Fitxategiko elementuaren gainean kokatu }
   read(f, rdIbilgailua) ;  { Fitxategitik elementu osoa irakurri }
   
   rAbiadura := 1.1 * rdIbilgailua.rAldiunekoAbiadura ;    { %10a inkrementatu }
   rdIbilgailua.rAldiunekoAbiadura := rAbiadura ;          { elementua berriztu }
   
   seek(f, iPosizioa) ;     { Fitxategiko elementuaren gainean kokatu }
   write(f, rdIbilgailua) ; { Fitxategian  elementu osoa idatzi }
     
   close(f) ;               { Fitxategia itxi }
end ;


function fnbo4ZifraDira(sMatrikulaZifrak: tsKateZifrak): boolean ;
var
   k: integer ;
   boBai4ZifraDira: boolean ;
begin
   boBai4ZifraDira := TRUE ;
   for k:=1 to 4 do
   begin
      if (sMatrikulaZifrak[k] <'0') or (sMatrikulaZifrak[k] > '9') then
      begin
         writeln(k, '. posizioko ''', sMatrikulaZifrak[k], ''' karakterea ez da zifra bat, 4 zifrak errepikatu.') ;
         boBai4ZifraDira := FALSE ;
      end ;
   end ;
   fnbo4ZifraDira := boBai4ZifraDira ;
end ;


procedure MatrikulaZehaztu(var sMatrikulaBat: tsKateMatrikula) ;
var
   sMatrikulaZifrak: tsKateZifrak ;
   cHautapena: char ;
begin
   repeat
      write('Matrikularen ZZZZ lau zifrak eman: ') ;
      readln(sMatrikulaZifrak) ;
   until fnbo4ZifraDira(sMatrikulaZifrak) ;
   
   writeln('Matrikularen letrak ''BPK'' edo ''KHS'' direnez, bat hautatu:') ;
   writeln('   ''BPK'' bada 1 aukeratu') ;
   writeln('   ''KHS'' bada 2 aukeratu') ;
   repeat
      write('Zure hautapena aukeratu -----> ') ;
      readln(cHautapena) ;
   until (cHautapena = '1') or (cHautapena = '2') ; 
   
   if cHautapena = '1' then  
      sMatrikulaBat := sMatrikulaZifrak + ' BPK'
   else
      sMatrikulaBat := sMatrikulaZifrak + ' KHS' ;
end ;

(* ---------------------- PROGRAMA NAGUSIA ---------------------- *)

var
   sFitxIzen: tsKatea ;
   sMatrikulaBat: tsKateMatrikula ;
   iPosizioa: integer ;
begin
   writeln ;
   writeln ;
   writeln ;   

   writeln('Ibilgailuen informazioa gordeko duen fitxategiaren izena eman ezazu.') ;
   write('Adibidez, ''Autoak.dat'' izena: ') ;
   readln(sFitxIzen) ; 
   sFitxIzen := sBIDEA + sFitxIzen ;
   writeln ;
   
   if fileExists(sFitxIzen) then     { Konprobatu ea existitzen den ala ez }
   begin
      writeln(sFitxIzen, ' fitxategia existitzen da.') ;
      writeln('Hona hemen bere edukia:') ;
      FitxategiarenEdukiaIkusi(sFitxIzen) ;
   end
   else
   begin
      writeln(sFitxIzen, ' fitxategirik ez dago.') ;
      writeln('Oraintxe sortuko dugu.') ;
      FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen) ;      
      writeln('Sortutako fitxategiaren edukia:') ; 
      FitxategiarenEdukiaIkusi(sFitxIzen) ;     
   end ;

   writeln ;
   writeln('Abiadura aldatu nahi zaion ibilgailuaren ''ZZZZ LLL'' formatuko matrikula zehaztu.') ;
   MatrikulaZehaztu(sMatrikulaBat) ;   
   writeln('''', sMatrikulaBat, ''' matrikuladun ibilgailuari abiadura inkrementatu.') ;
      
   iPosizioa := fniMatrikulaFitxategianBilatu(sFitxIzen, sMatrikulaBat) ;
   if iPosizioa = -1 then
      writeln('''', sMatrikulaBat, ''' matrikula ez da aurkitzen fixategian!!!')    
   else
   begin
      FitxategianElementuBatAldatu(sFitxIzen, iPosizioa) ;
      writeln ;
      writeln('Aldatutako fitxategiaren edukia:') ; 
      FitxategiarenEdukiaIkusi(sFitxIzen) ;   
   end ;
      
   writeln ;
   write('RETURN sakatu programa bukatzeko') ;
   writeln ;
   readln ;
end.

Programaren balizko exekuzio bat hurrrengo irudian erakusten da: