| ZER DAKIDAN: Zenbakiak, karaktereak, kateak, arrayak, erregistroak eta fitxategiak lantzeko gai naiz. ZER IKASIKO DUDAN: Datuak modu iraunkorrean gorde ahal izateko file datu-motako fitxategi bat prozesatzen dakit. Ariketa honetan fitxategi batetik abiatuta fitxategi berriak nola sortu ikasiko dut. |
ESKATZEN DEN PROGRAMA
Erregistroen fitxategi batzuekin lan egingo dugu. Lau fitxategien elementuak bi eremuko erregistroak izango dira. Lehen eremua ibilgailuaren matrikula izango da (matrikula guztien letrak BBB dira eta matrikula bakoitzaren zifrak sekuentzialki doaz 0001etik hasita). Bigarren eremua ibilgailuaren aldiuneko abiadura izango da eta bere balioa auzaz lortuko dugu.
Erregistroaren egitura honako hau da:
| 1. eremua | sMatrikula | 8 karaktereko kate bat, kate desberdinak izango dira zerrendaren elementu guztientzat |
| 2. eremua | rAldiunekoAbiadura | zenbaki erreal bat |
Gure programak fitxategiaren izena eskatuko du (Autoak.dat adibidez) eta erabiltzaileak emandako sarrerarekin fitxategiaren existentzia konprobatuko du, ondoko bi bide irekiz:
- Autoak.dat fitxategia existitzen bada, bere edukia pantailaratuko da eta elementu berriak gehituko dira fitxategiaren amaieran 25. Ariketa: fitxategiak (I) programan bezala. Ondoren, hiru fitxategi berri sortuko dira:
- Batezbesteko aritmetikoaren abiadura berdintsuak duten elementuak Autoak_B.dat izeneko fitxategiak bilduko ditu
- Batezbesteko aritmetikoa baino handiago abiadura duten elementuak Autoak_H.dat izeneko fitxategiak bilduko ditu
- Batezbesteko aritmetikoa baino txikiago abiadura duten elementuak Autoak_T.dat izeneko fitxategiak bilduko ditu
- Autoak.dat fitxategia existitzen ez bada, fitxategi berria sortuko da 25. Ariketa: fitxategiak (I) programan bezala. Ondoren, hiru fitxategi berri sortuko dira:
- Batezbesteko aritmetikoaren abiadura berdintsuak duten elementuak Autoak_B.dat izeneko fitxategiak bilduko ditu
- Batezbesteko aritmetikoa baino handiago abiadura duten elementuak Autoak_H.dat izeneko fitxategiak bilduko ditu
- Batezbesteko aritmetikoa baino txikiago abiadura duten elementuak Autoak_T.dat izeneko fitxategiak bilduko ditu
{ 26. ariketa: auto bat radar atari azpitik igartzean ondoko datuak }
{ jaso eta gordetzen dira fitxategi batean: }
{ - Matrikula, karkatere-kate bat }
{ - Aldi uneko abiadura, zenbaki erreal bat }
{ Datuak erdi automatikoki lortuko dira: matrikulen letrak BBB dira }
{ zifrak sekuentzialki doaz 0001etik hasita, abiaduren balioak auzaz }
{ sortuko dira. Ondorioz, matrikulak desberdinak izango dira. }
{ Fitxategia existitzen ez bada, sortuko da eta datuz bete ondoren }
{ bere edukia pantailaratuko da eta aldiuneko abiaduren batezbesteko }
{ aritmetikoaa kalkulatuko da. Fitxategia lehendik existitzen bada }
{ bere uneko edukia pantailaratuko da, gero elementu berriak gehitu }
{ ondoren berriro erakutsiko dira fitxategiaren eduki berria eta }
{ abiaduren batezbesteko aritmetikoa. }
{ Ibilgailuen aldiuneko abiaduren batezbesteko aritmetikoa kalkulatu }
{ ondoren, hiru fitxategi berri lortuko dira: }
{ 1. Batezbestekoaren "bezalako" abiadura dutenen elementuena }
{ 2. Batezbestekoa baino abiadura handiago dutenen elementuena }
{ 3. Batezbestekoa baino abiadura txikiago dutenen elementuena }
program Ariketa__26;
uses
sysutils; { fileExists() funtzioak behar duelako }
const
//sBIDEA = 'C:\Radarrak\'; (* Windows *)
sBIDEA = '/Users/jesusromouriarte/Desktop/Radarrak/'; (* Mac *)
type
tsKatea = string[250]; { Fitxategiaren izen osoa luzea izan daitekeelako }
tsKateMatrikula = string[8]; { ZZZZ-LLL formatuko matrikula }
trdIbilgailua = record
sMatrikula : tsKateMatrikula;
rAldiunekoAbiadura: real;
end;
tfrdFitxategia = file of trdIbilgailua;
procedure IbilgailuarenInformazioaJaso(var rdIbilgailua: trdIbilgailua; i: integer);
var
sMatrikulaZifra: tsKateMatrikula;
begin
Str(i, sMatrikulaZifra) ;
if i < 10 then
sMatrikulaZifra := '000' + sMatrikulaZifra;
if (i >= 10) and (i < 100) then
sMatrikulaZifra := '00' + sMatrikulaZifra;
if i >= 100 then
sMatrikulaZifra := '0' + sMatrikulaZifra;
rdIbilgailua.sMatrikula := sMatrikulaZifra + ' BBB';
rdIbilgailua.rAldiunekoAbiadura := 50 + 130*random; (* 50.0 eta 179.99 artean *)
end;
procedure IbilgailuarenInformazioaErakutsi(const rdIbilgailua: trdIbilgailua);
begin
write(rdIbilgailua.sMatrikula:15);
write(rdIbilgailua.rAldiunekoAbiadura:14:2);
writeln;
end;
procedure FitxategiarenEdukiaErakutsi(sIzenFitxOsoa: tsKatea);
var
fOsoa: tfrdFitxategia;
rdDatua: trdIbilgailua;
begin
assign(fOsoa, sIzenFitxOsoa);
reset(fOsoa); { Fitxategia ireki baina barrukoa ez borratu!!! }
writeln('Matrikula':38, 'Abiadura':14);
writeln('=========':38, '========':14);
{ Datuak kudeatu for bitartez }
while not eof(fOsoa) do
begin
read(fOsoa,rdDatua); { Irakurri eta hurrengora pasa }
write(filePos(fOsoa):10, '. elementua: ');
IbilgailuarenInformazioaErakutsi(rdDatua);
end;
close(fOsoa); { Fitxategia itxi }
end;
procedure FitxategiaSortuEtaDatuzBete(sIzenFitxOsoa: tsKatea);
var
fOsoa: tfrdFitxategia;
rdDatua: trdIbilgailua;
iZenbat, i: integer;
begin
assign(fOsoa, sIzenFitxOsoa);
rewrite(fOsoa); { Fitxategia sortu, eta existitzekotan bere edukia borratu }
write('Zenbat elementu izango ditu fitxategiak (adibidez 15): ');
readln(iZenbat);
randomize;
for i:=1 to iZenbat do
begin
IbilgailuarenInformazioaJaso(rdDatua, i);
write(fOsoa, rdDatua); { Fitxategian idatzi eta hurrengo elementura pasa }
end;
close(fOsoa); { Fitxategia itxi }
end;
function fnsFitxategiarenAzkenElementukoMatrikulaLortu(sIzenFitxOsoa: tsKatea): tsKateMatrikula;
var
fOsoa: tfrdFitxategia;
rdDatua: trdIbilgailua;
begin
assign(fOsoa, sIzenFitxOsoa);
reset(fOsoa); { Fitxategia ireki baina barrukoa ez borratu!!! }
seek(fOsoa, fileSize(fOsoa)-1); { Fitxategiaren azken elementuaren gainean kokatu }
read(fOsoa, rdDatua);
fnsFitxategiarenAzkenElementukoMatrikulaLortu := rdDatua.sMatrikula;
close(fOsoa); { Fitxategia itxi }
end ;
procedure FitxategiariDatuakGehitu(sIzenFitxOsoa: tsKatea);
var
fOsoa: tfrdFitxategia;
rdDatua: trdIbilgailua;
iZenbat, i: integer;
sMatrik, sMatrikulaZifra: tsKateMatrikula;
iMatrikulaZifra: integer ;
begin
sMatrik := fnsFitxategiarenAzkenElementukoMatrikulaLortu(sIzenFitxOsoa);
sMatrikulaZifra := Copy(sMatrik, 1, 4);
Val(sMatrikulaZifra, iMatrikulaZifra);
assign(fOsoa, sIzenFitxOsoa);
reset(fOsoa); { Fitxategia ireki baina barrukoa ez borratu!!! }
seek(fOsoa, fileSize(fOsoa)); { Fitxategiaren bukaeran kokatu }
write('Zenbat elementu gehituko dira fitxategira (adibidez 7): ');
readln(iZenbat);
for i:=iMatrikulaZifra+1 to iMatrikulaZifra+iZenbat do
begin
IbilgailuarenInformazioaJaso(rdDatua, i);
write(fOsoa, rdDatua); { Fitxategian idatzi eta hurrengo elementura pasa }
end;
close(fOsoa); { Fitxategia itxi }
end;
function fnrBatezbestekoAbiaduraKalkulatu(sIzenFitxOsoa: tsKatea): real;
var
fOsoa: tfrdFitxategia;
rdDatua: trdIbilgailua;
rMetatua: real;
begin
assign(fOsoa, sIzenFitxOsoa);
reset(fOsoa); { Fitxategia ireki baina barrukoa ez borratu!!! }
rMetatua := 0.0;
while not eof(fOsoa) do
begin
read(fOsoa,rdDatua); { Irakurri eta hurrengora pasa }
rMetatua := rMetatua + rdDatua.rAldiunekoAbiadura;
end;
fnrBatezbestekoAbiaduraKalkulatu := rMetatua / fileSize(fOsoa);
close(fOsoa); { Fitxategia itxi }
end ;
procedure HiruFitxategienIzenakEraiki( sIzenFitxOsoa: tsKatea;
var sIzenFitxBerdin,
sIzenFitxHandi,
sIzenFitxTxiki: tsKatea);
var
iBanatzileaNon: integer;
cBanatzailea: char;
sIzenLuzapen, sIzena, sLuzapena: tsKatea;
begin
//sBIDEA := 'C:\Radarrak\'; (* Windows *)
//cBanatzailea := '\'; (* Windows *)
//sBIDEA := '/Users/jesusromouriarte/Desktop/Radarrak/'; (* Mac *)
cBanatzailea := '/'; (* Mac *)
sIzenLuzapen := sIzenFitxOsoa;
repeat
//writeln('|||>', sIzenLuzapen, '<|||');
iBanatzileaNon := Pos(cBanatzailea, sIzenLuzapen);
Delete(sIzenLuzapen, 1, iBanatzileaNon);
//writeln('===>', sIzenLuzapen, '<===');
until iBanatzileaNon = 0;
cBanatzailea := '.';
iBanatzileaNon := Pos(cBanatzailea, sIzenLuzapen);
if iBanatzileaNon <> 0 then
begin
sIzena := Copy(sIzenLuzapen, 1, iBanatzileaNon-1);
sLuzapena := Copy(sIzenLuzapen, iBanatzileaNon+1, Length(sIzenLuzapen)-iBanatzileaNon);
//writeln('Izena======>', sIzena, '<===');
//writeln('Luzapena===>', sLuzapena, '<===');
sIzenFitxBerdin := sBIDEA + sIzena + '_B.' + sLuzapena;
sIzenFitxHandi := sBIDEA + sIzena + '_H.' + sLuzapena;
sIzenFitxTxiki := sBIDEA + sIzena + '_T.' + sLuzapena ;
end
else
begin
sIzena := sIzenLuzapen;
//writeln('Izena======>', sIzena, '<===');
sIzenFitxBerdin := sBIDEA + sIzena + '_B';
sIzenFitxHandi := sBIDEA + sIzena + '_H';
sIzenFitxTxiki := sBIDEA + sIzena + '_T';
end;
//writeln('sIzenFitxTxiki===>', sIzenFitxTxiki, '<===');
end ;
procedure HiruFitxategiakLortu(sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki: tsKatea; rBBA: real);
var
fOsoa, fBerdin, fHandi, fTxiki: tfrdFitxategia;
rdDatua: trdIbilgailua;
rDoitasuna: real;
begin
assign(fOsoa, sIzenFitxOsoa);
assign(fBerdin, sIzenFitxBerdin);
assign(fHandi, sIzenFitxHandi);
assign(fTxiki, sIzenFitxTxiki);
reset(fOsoa); { Fitxategia ireki baina barrukoa ez borratu!!! }
rewrite(fBerdin); { Fitxategia sortu, eta existitzekotan bere edukia borratu }
rewrite(fHandi); { Fitxategia sortu, eta existitzekotan bere edukia borratu }
rewrite(fTxiki); { Fitxategia sortu, eta existitzekotan bere edukia borratu }
rDoitasuna := (rBBA * 5) / 100; (* doitasuna BBAren %5a *)
while not eof(fOsoa) do
begin
read(fOsoa,rdDatua); { Irakurri eta hurrengora pasa }
if abs(rdDatua.rAldiunekoAbiadura - rBBA) < rDoitasuna then
write(fBerdin,rdDatua)
else
if rdDatua.rAldiunekoAbiadura > rBBA then
write(fHandi,rdDatua)
else
write(fTxiki,rdDatua)
end;
close(fOsoa); { Fitxategia itxi }
close(fBerdin); { Fitxategia itxi }
close(fTxiki); { Fitxategia itxi }
close(fHandi); { Fitxategia itxi }
end ;
(* =====================- PROGRAMA NAGUSIA =====================- *)
var
sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki: tsKatea;
rAbiadurenBBA: real;
begin
writeln;
writeln;
writeln;
writeln('Ibilgailuen informazioa gordeko duen fitxategiaren izena eman ezazu.');
write('Adibidez, ''Autoak.dat'' izena: ');
readln(sIzenFitxOsoa);
sIzenFitxOsoa := sBIDEA + sIzenFitxOsoa;
writeln;
if fileExists(sIzenFitxOsoa) then { Konprobatu ea existitzen den ala ez }
begin
writeln(sIzenFitxOsoa, ' fitxategia existitzen da.');
writeln('Hona hemen bere edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxOsoa);
rAbiadurenBBA := fnrBatezbestekoAbiaduraKalkulatu(sIzenFitxOsoa);
writeln('Aldiuneko abiaduren batezbesteko aritmetikoa: ', rAbiadurenBBA:0:2, ' Km/h');
writeln;
writeln('Elementu berriak gehituko dira:');
FitxategiariDatuakGehitu(sIzenFitxOsoa);
FitxategiarenEdukiaErakutsi(sIzenFitxOsoa);
rAbiadurenBBA := fnrBatezbestekoAbiaduraKalkulatu(sIzenFitxOsoa);
writeln('Aldiuneko abiaduren batezbesteko aritmetikoa: ', rAbiadurenBBA:0:2, ' Km/h');
writeln;
HiruFitxategienIzenakEraiki(sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki);
HiruFitxategiakLortu(sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki, rAbiadurenBBA);
writeln('BBAren berdineko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxBerdin);
writeln('BBA baino handiagoko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxHandi);
writeln('BBA baino txikiagoko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxTxiki);
end
else
begin
writeln(sIzenFitxOsoa, ' fitxategirik ez dago.');
writeln('Oraintxe sortuko dugu.');
FitxategiaSortuEtaDatuzBete(sIzenFitxOsoa);
writeln('Sortutako fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxOsoa);
rAbiadurenBBA := fnrBatezbestekoAbiaduraKalkulatu(sIzenFitxOsoa);
writeln('Aldiuneko abiaduren batezbesteko aritmetikoa: ', rAbiadurenBBA:0:2, ' Km/h');
writeln;
HiruFitxategienIzenakEraiki(sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki);
HiruFitxategiakLortu(sIzenFitxOsoa, sIzenFitxBerdin, sIzenFitxHandi, sIzenFitxTxiki, rAbiadurenBBA);
writeln('BBAren berdineko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxBerdin);
writeln('BBA baino handiagoko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxHandi);
writeln('BBA baino txikiagoko fitxategiaren edukia:');
FitxategiarenEdukiaErakutsi(sIzenFitxTxiki);
end;
writeln;
write('RETURN sakatu programa bukatzeko');
writeln;
readln;
end.
Programaren balizko hiru exekuzio hurrrengo irudietan erakusten dira:
Programaren aurreko hiru exekuzioetan sortu diren hamabi fitxategien ezaugarriak ikus daitezke. Azpimarratzen dugu fitxategien elementu bakoitzak 20 byte hartzen dituela diskoan, irudi honetan ikus daitekeen bezala:
iruzkinik ez:
Argitaratu iruzkina
Iruzkinen bat idazteko Google-ko kontu bat behar duzu. Iruzkin guztien moderazio-ardura blogeko administratzaileari dagokio.