| ZER DAKIDAN: Zenbakiak, karaktereak, kateak, arrayak, erregistroak eta fitxategiak lantzeko gai naiz. Halaber, array laguntzaile batean oinarrituriko hiru algoritmo 28. Ariketa: fitxategiak (IV) atalean ikasi ditut. ZER IKASIKO DUDAN: Erregistroen fitxategi batean, fitxategi laguntzaile batean oinarriturik ondoko bi algoritmoak programatzen ikasiko ditut:
|
ESKATZEN DEN PROGRAMA
Erregistroen fitxategi batekin lan egingo dugu eta algoritmo batzuk aplikatuko dizkiogu fitxategiari. Fitxategiaren elementuak hiru eremuko erregistroak izango dira. Lehen eremua ibilgailuaren matrikula izango da (matrikula guztien letrak BPK edo KHS izango dira auzaz hautaturik, eta matrikulen 4 zifrak programak aukeratuko ditu ere (programak zainduko du ibilgailuen matrikulak ez direla errepikatzen fitxategian). Bigarren eremua ibilgailuaren mota adierazteko karaktere bat izango da eta auzaz eskuratuko du programak. Hirugarren eremua aldiuneko abiadura izango da eta bere balio erreala auzaz lortuko dugu ere.
Erregistroaren egitura honako hau da:
| 1. eremua | sMatrikula | 8 karaktereko kate bat, 'ZZZZ LLL' formatuko kate desberdinak izango dira fitxategiaren elementu guztientzat |
| 2. eremua | cIbilgailuMota | karaktere bat |
| 3. eremua | rAldiunekoAbiadura | zenbaki erreal bat |
Gure programak fitxategiaren izena eskatuko du (Bolidoak.dat adibidez) hainbat elementuren informazioa gordeko du. Datuen fitxategia abiaduren arabera sailkatu nahi da baina array laguntzailerik gabe, datu-egitura laguntzailea beste fitxategi bat izango da Laguna.dat izeneko fitxategia alegia.
Programa honek burutuko dituen bi operazioak hauek dira:
- Elementu berri baten datuak teklatuz jaso eta fitxategiaren posizio jakin batean txertatuko da, honela:
- Fitxategi laguntzailea: Laguna.dat
- Non txertatu: iPosizioa
- Algoritmoa: FOR batekin hasi eta WHILE batekin bukatu
- Ibilgailuen mota bat aukeratu eta mota horretako ibilgailu guztiak fitxategitik kendu, honela:
- Fitxategi laguntzailea: Laguna.dat
- Non txertatu: iPosizioa
- Algoritmoa: WHILE bat eta bere barnean IF batekin
{ 29. ariketa: auto bat radar atari azpitik igartzean ondoko datuak }
{ jaso eta gordetzen dira fitxategi batean: }
{ - Matrikula, karkatere-kate bat }
{ - Ibilgailu mota, karaktere bat }
{ - Aldi uneko abiadura, zenbaki erreal bat }
{ Datuak erdi automatikoki lortuko dira auzazko balioak sortuz. }
{ Matrikula bereko autoak ez direlako onartzen, matrikula jakin bat }
{ sortzean, fitxategian berria izango dela frogatu beharra dago. }
{ Fitxategia existitzen ez bada, sortuko da eta datuz bete ondoren }
{ bere edukia pantailaratuko da. Fitxategia lehendik existitzen bada }
{ duen edukia pantailaratuko da. }
{ Fitxategia lortuta, bi eragiketa egingo dira: }
{ 1. Fitxategiaren erdiko posizio jakin batean elementu berri bat }
{ tartekatu }
{ 2. Fitxategitik elementu batzuk kendu }
{ Egitura laguntzailearen datu-mota: file }
program Ariketa_29 ;
uses
SysUtils; { fileexists() funtzioak behar duelako }
const
//sBIDEA = 'C:\Radarrak\'; (* Windows *)
sBIDEA = '/Users/jesusromouriarte/Desktop/Radarrak/'; (* Mac *)
type
tsKatea = string[250]; { Fitxategiaren izen osoa luzea izan daitekeelako }
tsKateMatrikula = string[8] ; { ZZZZ LLL formatuko matrikula }
tsKateZifrak = string[4] ; { Matrikularen ZZZZ zatirako }
trdIbilgailua = record
sMatrikula : tsKateMatrikula ;
cIbilgailuMota : char ;
rAldiunekoAbiadura: real ;
end ;
tfrdFitxategia = file of trdIbilgailua ;
procedure IbilgailuarenInformazioaErakutsi(const rdIbilgailua: trdIbilgailua) ;
begin
write(rdIbilgailua.sMatrikula:15) ;
write(rdIbilgailua.cIbilgailuMota:9) ;
write(rdIbilgailua.rAldiunekoAbiadura:14:2) ;
writeln ;
end ;
procedure FitxategiarenEdukiaIkusi(sFitxIzen: tsKatea) ;
var
f: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
begin
assign(f, sFitxIzen) ;
reset(f) ;
writeln('Matrikula Mota':47, 'Abiadura':14) ;
writeln('--------- ----':47, '--------':14) ;
{ Datuak kudeatu for bitartez}
while not eof(f) do
begin
read(f,rdDatua) ;
write(filepos(f):10, '. elementua: ') ;
IbilgailuarenInformazioaErakutsi(rdDatua) ;
end ;
close(f) ;
end ;
procedure IbilgailuarenInformazioaJaso(var rdIbilgailua: trdIbilgailua) ;
var
iAusazkoa, iKont: integer ;
sMatrikula, sMatrikulaZifra: tsKateMatrikula ;
begin
sMatrikula := '' ;
for iKont:=1 to 4 do
begin
iAusazkoa := random(10) ;
Str(iAusazkoa, sMatrikulaZifra) ;
sMatrikula := sMatrikula + sMatrikulaZifra ;
end ;
iAusazkoa := random(2) ;
case iAusazkoa of
0: rdIbilgailua.sMatrikula := sMatrikula + ' KHS' ;
1: rdIbilgailua.sMatrikula := sMatrikula + ' BPK' ;
end ;
iAusazkoa := random(4) ;
case iAusazkoa of
0: rdIbilgailua.cIbilgailuMota := 'A' ;
1: rdIbilgailua.cIbilgailuMota := 'B' ;
2: rdIbilgailua.cIbilgailuMota := 'C' ;
3: rdIbilgailua.cIbilgailuMota := 'D' ;
end ;
rdIbilgailua.rAldiunekoAbiadura := 50 + 130*random; (* 50.0 eta 179.99 artean *)
end ;
procedure FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
rewrite(f) ; { Fitxategia sortu }
write(f, rdIbilgailua) ; { Lehen elementua gorde }
close(f) ; { Fitxategia itxi }
end ;
procedure FitxategianElementuBatGehitu(sFitxIzen: tsKatea; const rdIbilgailua: trdIbilgailua) ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki baina barrukoa ez borratu!!! }
seek(f, filesize(f)) ; { Fitxategiaren bukaeran kokatu }
write(f, rdIbilgailua) ; { Fitxategian idatzi eta hurrengo elementura pasa }
close(f) ; { Fitxategia itxi }
end ;
{ Bilaketa gauzatzeko funtzioan while-DO egitura erabiltzen da }
function fniMatrikulaFitxategianBilatu(sFitxIzen: tsKatea; sMatrik: tsKateMatrikula): integer ;
var
f: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
boAurkitua: boolean ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki baina barrukoa ez borratu!!! }
boAurkitua := FALSE ;
while not eof(f) and not boAurkitua do
begin
read(f,rdDatua) ;
if rdDatua.sMatrikula = sMatrik then
boAurkitua := TRUE
end ;
if boAurkitua then
fniMatrikulaFitxategianBilatu := filepos(F) - 1
else
fniMatrikulaFitxategianBilatu := -1 ; { -1 gezurrezko posizioa litzateke }
close(f) ; { Fitxategia itxi }
end ;
procedure FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen: tsKatea) ;
var
rdIbilgailua: trdIbilgailua ;
iZenbat, iIndizea, iPosizioa: integer ;
begin
repeat
write('Zenbat elementu izango ditu fitxategiak (adibidez 150): ') ;
readln(iZenbat) ;
until iZenbat > 0 ;
writeln ;
randomize ;
IbilgailuarenInformazioaJaso(rdIbilgailua) ;
FitxategiaSortuEtaLehenElementuaGorde(sFitxIzen, rdIbilgailua) ; { Lehen matrikula beti izango da berria }
for iIndizea:=2 to iZenbat do
begin
repeat
IbilgailuarenInformazioaJaso(rdIbilgailua) ;
iPosizioa := fniMatrikulaFitxategianBilatu(sFitxIzen, rdIbilgailua.sMatrikula) ;
if iPosizioa <> -1 then
begin
writeln('''', rdIbilgailua.sMatrikula, ''' matrikula fitxategiaren ', iPosizioa, '. posizioan dago!!!') ;
writeln('Aurrera egiteko RETURN sakatu!') ;
readln ;
end
else
FitxategianElementuBatGehitu(sFitxIzen, rdIbilgailua) ; { Matrikula berria da }
until iPosizioa = -1 ;
end ;
end ;
function fnbo4ZifraDira(sMatrikulaZifrak: tsKateZifrak): boolean ;
var
k: integer ;
boBai4ZifraDira: boolean ;
begin
boBai4ZifraDira := TRUE ;
for k:=1 to 4 do
begin
if (sMatrikulaZifrak[k] <'0') or (sMatrikulaZifrak[k] > '9') then
begin
writeln(k, '. posizioko ''', sMatrikulaZifrak[k], ''' karakterea ez da zifra bat, 4 zifrak errepikatu.') ;
boBai4ZifraDira := FALSE ;
end ;
end ;
fnbo4ZifraDira := boBai4ZifraDira ;
end ;
procedure MatrikulaZehaztu(var sMatrikulaBat: tsKateMatrikula) ;
var
sMatrikulaZifrak: tsKateZifrak ;
cHautapena: char ;
begin
repeat
write('Matrikularen ZZZZ lau zifrak eman: ') ;
readln(sMatrikulaZifrak) ;
until fnbo4ZifraDira(sMatrikulaZifrak) ;
writeln('Matrikularen letrak ''BPK'' edo ''KHS'' direnez, bat hautatu:') ;
writeln(' ''BPK'' bada 1 aukeratu') ;
writeln(' ''KHS'' bada 2 aukeratu') ;
repeat
write('Zure hautapena aukeratu -----> ') ;
readln(cHautapena) ;
until (cHautapena = '1') or (cHautapena = '2') ;
if cHautapena = '1' then
sMatrikulaBat := sMatrikulaZifrak + ' BPK'
else
sMatrikulaBat := sMatrikulaZifrak + ' KHS' ;
end ;
procedure IbilgailuarenInformazioaTeklatuz(sFitxIzen: tsKatea; var rdIbilgailua: trdIbilgailua) ;
var
sMatrikulaBat: tsKateMatrikula ;
iPosizioa: integer ;
begin
repeat
writeln('Ibilgailuaren ''ZZZZ LLL'' formatuko matrikula zehaztu.') ;
MatrikulaZehaztu(sMatrikulaBat) ;
iPosizioa := fniMatrikulaFitxategianBilatu(sFitxIzen, sMatrikulaBat) ;
if iPosizioa <> -1 then
writeln('''', sMatrikulaBat, ''' matrikula fixategian dago eta ezin da errepikatu!!!') ;
until iPosizioa = -1 ;
rdIbilgailua.sMatrikula := sMatrikulaBat ;
repeat
write('''', sMatrikulaBat, ''' matrikuladun ibilgailua zein motatakoa da? (A, B, C edo D) ') ;
readln(rdIbilgailua.cIbilgailuMota) ;
rdIbilgailua.cIbilgailuMota := upcase(rdIbilgailua.cIbilgailuMota) ;
until (rdIbilgailua.cIbilgailuMota >= 'A') and (rdIbilgailua.cIbilgailuMota <= 'D') ;
repeat
write('''', sMatrikulaBat, ''' matrikuladun ibilgailuaren abiadura (50.0 eta 179.9 artekoa): ') ;
readln(rdIbilgailua.rAldiunekoAbiadura) ;
until (rdIbilgailua.rAldiunekoAbiadura >= 50.0) and (rdIbilgailua.rAldiunekoAbiadura < 180.0) ;
end ;
function fniFitxategiarenElementuKopurua(sFitxIzen: tsKatea): integer ;
var
f: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki }
fniFitxategiarenElementuKopurua := filesize(f) ; { Elementuen kopurua }
close(f) ; { Fitxategia itxi }
end ;
procedure FitxategiaEzabatuEtaBerrizendatu(sFitxIzen, sFitxIzenLagun: tsKatea) ;
var
f, fLaguntzailea: tfrdFitxategia ;
begin
assign(f, sFitxIzen) ;
assign(fLaguntzailea, sFitxIzenLagun) ;
erase(f) ;
rename(fLaguntzailea, sFitxIzen) ;
end ;
procedure FitxategianElementuBatTxertatu(sFitxIzen, sFitxIzenLagun: tsKatea;
const rdIbilgailua: trdIbilgailua;
iPosizioa: integer) ;
var
f, fLaguntzailea: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
iKont: integer ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki }
assign(fLaguntzailea, sFitxIzenLagun) ;
rewrite(fLaguntzailea) ; { Fitxategi laguntzailea sortu }
if iPosizioa = 1 then { iPosizioa = 1 denerako }
begin
write(fLaguntzailea, rdIbilgailua) ; { iPosizioa tokian elementua txertatu }
end
else
begin
for iKont:=1 to iPosizioa-1 do
begin
read(f, rdDatua) ; { Fitxategitik elementu osoa irakurri }
write(fLaguntzailea, rdDatua) ; { Elementu osoa zerrendan gorde }
end ;
write(fLaguntzailea, rdIbilgailua) ; { iPosizioa tokian elementua txertatu }
end ;
while not eof(f) do
begin
read(f, rdDatua) ; { Fitxategitik elementu osoa irakurri }
write(fLaguntzailea, rdDatua) ; { Elementua laguntzailean gorde }
end ;
close(f) ; { Fitxategia itxi }
close(fLaguntzailea) ; { Laguntzailea itxi }
FitxategiaEzabatuEtaBerrizendatu(sFitxIzen, sFitxIzenLagun) ;
end ;
procedure FitxategianElementuakKendu(sFitxIzen, sFitxIzenLagun: tsKatea; cMota: char) ;
var
f, fLaguntzailea: tfrdFitxategia ;
rdDatua: trdIbilgailua ;
begin
assign(f, sFitxIzen) ;
reset(f) ; { Fitxategia ireki }
assign(fLaguntzailea, sFitxIzenLagun) ;
rewrite(fLaguntzailea) ; { Fitxategi laguntzailea sortu }
while not eof(f) do
begin
read(f, rdDatua) ; { Fitxategitik elementu osoa irakurri }
if rdDatua.cIbilgailuMota <> cMota then
write(fLaguntzailea, rdDatua) ; { Elementua laguntzailean gorde }
end ;
close(f) ; { Fitxategia itxi }
close(fLaguntzailea) ; { Laguntzailea itxi }
FitxategiaEzabatuEtaBerrizendatu(sFitxIzen, sFitxIzenLagun) ;
end ;
(* ---------------------- PROGRAMA NAGUSIA ---------------------- *)
var
sFitxIzen, sFitxIzenLagun: tsKatea ;
iPosizioa, iZenbat: integer ;
rdIbilgailua: trdIbilgailua ;
cMota: char ;
begin
writeln ;
writeln ;
writeln ;
writeln('Ibilgailuen informazioa gordeko duen fitxategiaren izena eman ezazu.') ;
write('Adibidez, ''Autoak.dat'' izena: ') ;
readln(sFitxIzen) ;
sFitxIzen := sBIDEA + sFitxIzen ;
writeln ;
if fileexists(sFitxIzen) then { Konprobatu ea existitzen den ala ez }
begin
writeln(sFitxIzen, ' fitxategia existitzen da.') ;
writeln('Hona hemen bere edukia:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
end
else
begin
writeln(sFitxIzen, ' fitxategirik ez dago.') ;
writeln('Oraintxe sortuko dugu.') ;
FitxategiaSortuEtaDatuDesberdinezBete(sFitxIzen) ;
writeln('Sortutako fitxategiaren edukia:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
end ;
writeln ;
writeln('Txertatu nahi den elementu berriaren datuak jasoko dira jarraian...') ;
IbilgailuarenInformazioaTeklatuz(sFitxIzen, rdIbilgailua) ;
iZenbat := fniFitxategiarenElementuKopurua(sFitxIzen) ;
repeat
write('''', rdIbilgailua.sMatrikula, ''' zein posiziotan geratuko da txertaturik? (1 eta ', iZenbat + 1, ' artekoa): ') ;
readln(iPosizioa) ;
until (iPosizioa >= 1) and (iPosizioa <= iZenbat + 1) ;
sFitxIzenLagun := sBIDEA + 'Laguna.dat' ;
FitxategianElementuBatTxertatu(sFitxIzen, sFitxIzenLagun, rdIbilgailua, iPosizioa) ;
writeln ;
writeln('Fitxategia elementu berriarekin ', iPosizioa, '. posizioan:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
writeln ;
writeln('Mota bateko ibilgailu guztiak kenduko dira fitxategitik...') ;
repeat
write('Zein motatakoa ibilgailuak kenduko dira? (A, B, C edo D) ') ;
readln(cMota) ;
cMota := upcase(cMota) ;
until (cMota >= 'A') and (cMota <= 'D') ;
FitxategianElementuakKendu(sFitxIzen, sFitxIzenLagun, cMota) ;
writeln ;
writeln('Fitxategia ''', cMota, ''' motako elementurik gabe:') ;
FitxategiarenEdukiaIkusi(sFitxIzen) ;
writeln ;
write('RETURN sakatu programa bukatzeko') ;
writeln ;
readln ;
end.
Programaren balizko exekuzio bat hurrrengo hiru irudien artean erakusten da:
iruzkinik ez:
Argitaratu iruzkina
Iruzkinen bat idazteko Google-ko kontu bat behar duzu. Iruzkin guztien moderazio-ardura blogeko administratzaileari dagokio.